#[compute]
#version 450

// Workgroup size
layout(local_size_x = 4, local_size_y = 4, local_size_z = 4) in;

// Storage buffer
layout(set = 0, binding = 0, std430) buffer DataBuffer {
	float sample_points[];
} voxels;

layout(set = 0, binding = 1) uniform Params {
	int world_size;
	float threshold;
	float u_time;
} params;

layout(set = 0, binding = 2, std430) buffer SurfaceBuffer {
	float surface_points[]; 
} surface;

layout(set = 0, binding = 3, std430) buffer NormalsBuffer {
	float normals[];
} normal;

layout(set = 0, binding = 4, std430) buffer UVBuffer {
	vec2 UVs[];
} UV;

layout(set = 0, binding = 5, std430) buffer IndexBuffer {
	uint indices[];
} mesh_indices;

layout(set = 0, binding = 6, std430) buffer Counter {
	uint count;
} index_count;

layout(set = 0, binding = 7, std430) buffer ChunkPos {
	float position_array[];
} chunk;

uint index3(uint x, uint y, uint z) {
	return x + y * params.world_size + z * params.world_size * params.world_size;
}

void store_surface_point(uint idx, vec3 pos) {
	uint base = idx * 3u;
	surface.surface_points[base + 0u] = pos.x;
	surface.surface_points[base + 1u] = pos.y;
	surface.surface_points[base + 2u] = pos.z;
}

//
// Description : Array and textureless GLSL 2D/3D/4D simplex
//               noise functions.
//      Author : Ian McEwan, Ashima Arts.
//  Maintainer : stegu
//     Lastmod : 20201014 (stegu)
//     License : Copyright (C) 2011 Ashima Arts. All rights reserved.
//               Distributed under the MIT License. See LICENSE file.
//               https://github.com/ashima/webgl-noise
//               https://github.com/stegu/webgl-noise
//

vec3 mod289(vec3 x) {
	return x - floor(x * (1.0 / 289.0)) * 289.0;
}

vec4 mod289(vec4 x) {
	return x - floor(x * (1.0 / 289.0)) * 289.0;
}

vec4 permute(vec4 x) {
	return mod289(((x*34.0)+10.0)*x);
}

vec4 taylorInvSqrt(vec4 r)
{
	return 1.79284291400159 - 0.85373472095314 * r;
}

float snoise(vec3 v)
{
	const vec2  C = vec2(1.0/6.0, 1.0/3.0) ;
	const vec4  D = vec4(0.0, 0.5, 1.0, 2.0);

	// First corner
	vec3 i  = floor(v + dot(v, C.yyy) );
	vec3 x0 =   v - i + dot(i, C.xxx) ;

	// Other corners
	vec3 g = step(x0.yzx, x0.xyz);
	vec3 l = 1.0 - g;
	vec3 i1 = min( g.xyz, l.zxy );
	vec3 i2 = max( g.xyz, l.zxy );

	//   x0 = x0 - 0.0 + 0.0 * C.xxx;
	//   x1 = x0 - i1  + 1.0 * C.xxx;
	//   x2 = x0 - i2  + 2.0 * C.xxx;
	//   x3 = x0 - 1.0 + 3.0 * C.xxx;
	vec3 x1 = x0 - i1 + C.xxx;
	vec3 x2 = x0 - i2 + C.yyy; // 2.0*C.x = 1/3 = C.y
	vec3 x3 = x0 - D.yyy;      // -1.0+3.0*C.x = -0.5 = -D.y

	// Permutations
	i = mod289(i);
	vec4 p = permute( permute( permute(
	i.z + vec4(0.0, i1.z, i2.z, 1.0 ))
	+ i.y + vec4(0.0, i1.y, i2.y, 1.0 ))
	+ i.x + vec4(0.0, i1.x, i2.x, 1.0 ));

	// Gradients: 7x7 points over a square, mapped onto an octahedron.
	// The ring size 17*17 = 289 is close to a multiple of 49 (49*6 = 294)
	float n_ = 0.142857142857; // 1.0/7.0
	vec3  ns = n_ * D.wyz - D.xzx;

	vec4 j = p - 49.0 * floor(p * ns.z * ns.z);  //  mod(p,7*7)

	vec4 x_ = floor(j * ns.z);
	vec4 y_ = floor(j - 7.0 * x_ );    // mod(j,N)

	vec4 x = x_ *ns.x + ns.yyyy;
	vec4 y = y_ *ns.x + ns.yyyy;
	vec4 h = 1.0 - abs(x) - abs(y);

	vec4 b0 = vec4( x.xy, y.xy );
	vec4 b1 = vec4( x.zw, y.zw );

	//vec4 s0 = vec4(lessThan(b0,0.0))*2.0 - 1.0;
	//vec4 s1 = vec4(lessThan(b1,0.0))*2.0 - 1.0;
	vec4 s0 = floor(b0)*2.0 + 1.0;
	vec4 s1 = floor(b1)*2.0 + 1.0;
	vec4 sh = -step(h, vec4(0.0));

	vec4 a0 = b0.xzyw + s0.xzyw*sh.xxyy ;
	vec4 a1 = b1.xzyw + s1.xzyw*sh.zzww ;

	vec3 p0 = vec3(a0.xy,h.x);
	vec3 p1 = vec3(a0.zw,h.y);
	vec3 p2 = vec3(a1.xy,h.z);
	vec3 p3 = vec3(a1.zw,h.w);

	//Normalise gradients
	vec4 norm = taylorInvSqrt(vec4(dot(p0,p0), dot(p1,p1), dot(p2, p2), dot(p3,p3)));
	p0 *= norm.x;
	p1 *= norm.y;
	p2 *= norm.z;
	p3 *= norm.w;

	// Mix final noise value
	vec4 m = max(0.5 - vec4(dot(x0,x0), dot(x1,x1), dot(x2,x2), dot(x3,x3)), 0.0);
	m = m * m;
	return 105.0 * dot( m*m, vec4( dot(p0,x0), dot(p1,x1),
								   dot(p2,x2), dot(p3,x3) ) ) + params.threshold;
}

const ivec3 AXIS[3] = ivec3[](
	ivec3(1,0,0),
	ivec3(0,1,0),
	ivec3(0,0,1)
);

const ivec3 SURFACE_AXIS[8] = ivec3[](
	ivec3(1,0,0),
	ivec3(0,1,0),
	ivec3(0,0,1),
	ivec3(1,0,1),
	ivec3(0,1,1),
	ivec3(1,1,0),
	ivec3(1,1,1),
	ivec3(0,0,0)
);

// The 12 edges of a cube (pairs of corner indices 0-7)
const ivec2 EDGE_CORNERS[12] = ivec2[](
	ivec2(0,1), ivec2(1,2), ivec2(2,3), ivec2(3,0), // Bottom face edges
	ivec2(4,5), ivec2(5,6), ivec2(6,7), ivec2(7,4), // Top face edges
	ivec2(0,4), ivec2(1,5), ivec2(2,6), ivec2(3,7)  // Vertical edges
);

// The 8 corners of a cube
const ivec3 CORNERS[8] = ivec3[](
	ivec3(0,0,0), ivec3(1,0,0), ivec3(1,1,0), ivec3(0,1,0),
	ivec3(0,0,1), ivec3(1,0,1), ivec3(1,1,1), ivec3(0,1,1)
);

float get_noise_at(vec3 p) {

	float chunk_x = chunk.position_array[0] * -.5;
	float chunk_y = chunk.position_array[1] * -.5;
	float chunk_z = chunk.position_array[2] * -.5;
	p = p - vec3(chunk_x, chunk_y, chunk_z);
	p = p / 20.0;
	return snoise(p);
}

// Calculate normal using central difference
vec3 calculate_normal(vec3 p) {
	float e = 0.01; // Small epsilon
	float dx = get_noise_at(p + vec3(e, 0, 0)) - get_noise_at(p - vec3(e, 0, 0));
	float dy = get_noise_at(p + vec3(0, e, 0)) - get_noise_at(p - vec3(0, e, 0));
	float dz = get_noise_at(p + vec3(0, 0, e)) - get_noise_at(p - vec3(0, 0, e));
	return normalize(vec3(dx, dy, dz));
}

vec3 grid_to_world(uvec3 grid_id) {
	return (vec3(grid_id) - params.world_size / 2.0) * 0.5;
}

void main() {
	ivec3 id = ivec3(gl_GlobalInvocationID);
	if (any(greaterThanEqual(id, uvec3(params.world_size)))) return;

	vec3 p = grid_to_world(id);
	uint idx = index3(id.x, id.y, id.z);
	voxels.sample_points[idx] = get_noise_at(p);

	memoryBarrierBuffer();
	barrier();


	vec3 intersection_sum = vec3(0.0);
	uint count = 0;

	// Dual Contouring requires checking all 12 edges of the voxel.
	// If ANY of these 12 edges has a sign change, this voxel MUST have a vertex.
	for (int i = 0; i < 12; i++) {
		ivec3 c1_off = CORNERS[EDGE_CORNERS[i].x];
		ivec3 c2_off = CORNERS[EDGE_CORNERS[i].y];

		uvec3 c1 = id + uvec3(c1_off);
		uvec3 c2 = id + uvec3(c2_off);

		// Bounds check to prevent sampling noise outside the allocated buffer
		if (any(greaterThanEqual(c1, uvec3(params.world_size))) ||
			any(greaterThanEqual(c2, uvec3(params.world_size)))) continue;

		float d1 = get_noise_at(grid_to_world(c1));
		float d2 = get_noise_at(grid_to_world(c2));

		// Standard sign-change test
		if ((d1 < 0.0) != (d2 < 0.0) && d1 != -d2) {
			// Linear interpolation to find the exact crossing point on the edge
			float t = d1 / (d1 - d2);
			intersection_sum += mix(vec3(c1), vec3(c2), t);
			count++;
		}
	}

	if (count > 0) {
		vec3 avg_pos = intersection_sum / float(count);
		store_surface_point(idx, avg_pos);

		// Normals should be calculated at the exact averaged surface point
		vec3 world_p = (avg_pos - params.world_size / 2.0) * vec3(0.5);
		vec3 n = calculate_normal(world_p);
		uint base = idx * 3u;
		normal.normals[base + 0] = n.x;
		normal.normals[base + 1] = n.y;
		normal.normals[base + 2] = n.z;
	} else {
		// Explicitly mark empty voxels to prevent them from being used in Pass 2
		store_surface_point(idx, vec3(-1.0));
	}
}
